CREATE     PROC sp_CrossTab
  @TABLE       AS sysname,        -- Table to crosstab
  @onrows      AS nvarchar(128),  -- Grouping key values (on rows)
  @onrowsalias AS sysname = NULL, -- Alias for grouping column
  @oncols      AS nvarchar(128),  -- Destination columns (on columns)
  @sumcol      AS sysname = NULL  -- Data cells
AS
 
DECLARE
  @sql AS varchar(8000),
  @NEWLINE AS char(1)
 
SET @NEWLINE = CHAR(10)
 
-- step 1: beginning of SQL string
SET @sql =
  'SELECT' + @NEWLINE +
  '  ' + @onrows +
  CASE
    WHEN @onrowsalias IS NOT NULL THEN ' AS ' + @onrowsalias
    ELSE ''
  END
 
CREATE TABLE #keys(keyvalue nvarchar(100) NOT NULL PRIMARY KEY)
 
DECLARE @keyssql AS varchar(1000)
SET @keyssql =
  'INSERT INTO #keys ' +
  'SELECT DISTINCT CAST(' + @oncols + ' AS nvarchar(100)) ' +
  'FROM ' + @TABLE
 
EXEC (@keyssql)
 
DECLARE @KEY AS nvarchar(100)
SELECT @KEY = MIN(keyvalue) FROM #keys
 
WHILE @KEY IS NOT NULL
BEGIN
  SET @sql = @sql + ','                   + @NEWLINE +
    '  SUM(CASE CAST(' + @oncols +
                     ' AS nvarchar(100))' + @NEWLINE +
    '        WHEN N''' + @KEY +
           ''' THEN ' + CASE
                          WHEN @sumcol IS NULL THEN '1'
                          ELSE @sumcol
                        END + @NEWLINE +
    '        ELSE 0'                      + @NEWLINE +
    '      END) AS D' + @KEY
 
  SELECT @KEY = MIN(keyvalue) FROM #keys
  WHERE keyvalue > @KEY
END
 
SET @sql = @sql         + @NEWLINE +
  'FROM ' + @TABLE      + @NEWLINE +
  'GROUP BY ' + @onrows + @NEWLINE +
  'ORDER BY ' + @onrows
 
 PRINT @sql  + @NEWLINE -- For debug
EXEC (@sql)